Keysight CXG, EXG, and MXG X-Series Signal Generators Programming Guide 309
Creating and Downloading Waveform Files
Programming Examples
20 Num_points=200
30 ALLOCATE INTEGER Int_array(1:Num_points*2)
40 DEG
50 FOR I=1 TO Num_points*2 STEP 2
60 Int_array(I)=INT(32767*(SIN(I*360/Num_points)))
70 NEXT I
80 FOR I=2 TO Num_points*2 STEP 2
90 Int_array(I)=INT(32767*(COS(I*360/Num_points)))
100 NEXT I
110 PRINT "Data Generated"
120 Nbytes=4*Num_points
130 ASSIGN @PSG TO 719
140 ASSIGN @PSGb TO 719;FORMAT MSB FIRST
150 Nbytes$=VAL$(Nbytes)
160 Ndigits=LEN(Nbytes$)
170 Ndigits$=VAL$(Ndigits)
180 WAIT 1
190 OUTPUT @PSG USING "#,K";":MMEM:DATA ""WFM1:data_file"",#"
200 OUTPUT @PSG USING "#,K";Ndigits$
210 OUTPUT @PSG USING "#,K";Nbytes$
220 WAIT 1
230 OUTPUT @PSGb;Int_array(*)
240 OUTPUT @PSG;END
250 ASSIGN @PSG TO *
260 ASSIGN @PSGb TO *
270 PRINT
280 PRINT "*END*"
290 END
Program Comments
10: Program file name
20: Sets the number of points in the waveform.
30: Allocates integer data array for I and Q waveform points.
40: Sets HP BASIC to use degrees for cosine and sine functions.
To Next Page
Loading...
Need help?
General
