Fluke PM6669 - Programming Examples

Programming Examples
For HP-85 Controller
This program illustrate high measuring rate obtained
with High-speed dump.
The actual measuring function is selected by the user in
Local-mode. When the program runs, two beep’s can be
heard from the HP-85, Between these beep’s, the
counter performs 500 measurements and the result of
each measurement is transferred from the counter to the
HP-85.
The output rate is approximately 125 readings/second in
this example.
10 ! DEMO PROGRAM DUMP MODE
20 ! PM6669 WITH HP85 AS
30 ! CONTROLLER
40 ! DUMP MODE WITH FREE RUN ON
50 CLEAR
60 DIM Z$[7508] ! BUFFER FOR 500
MEASUREMENTS WITH 15 BYTES
70 DIM B$[14]
80 IOBUFFER Z$
90 LOCAL 710
100 DISP "SELECT FUNCTION IN LOCAL MODE!"
110 DISP "MEASURING TIME WILL BE"
120 DISP "SELECTED BY HP85 (SINGLE)!"
130 DISP "ANSWER Y WHEN READY TO START!"
140 INPUT A$
150 IF A$<>"Y" THEN 130
160 DISP "MAKE 500 MEASUREMENTS"
170 OUTPUT 710 ;"TRIG OFF,MTIME 0,OUTM 4"
180 BEEP
190 E=TIME
200 TRANSFER 710 TO Z$ FHS ; COUNT 7500
210 F=TIME
220 TIME
230 DISP "READY! ELAPSED TIME:";F-E;"s"
240 ! SHOW 5 RESULTS"
250 DISP "FIRST 5 RESULTS:"
260 FOR K=1 TO 5
270 ENTER Z$ ; B$
280 ! GET FORMULA CHARACTER
290 F$=B$[1,1]
300 ! GET MULTIPLYER CHARACTER
310 M$=B$[2,2]
320 ! EVALUATE REGISTER 1
330 R1=0
340 FOR I=1 TO 8
350 S=NUM(B$[I,I])-48
360 IF S>=10 THEN S=S-7
370 R1=R1*16+S
380 NEXT I
390 ! EVALUATE REGISTER 2
400 R2=0
410 FOR I=9 TO 14
420 S=NUM(B$[I,I])-48
430 IF S>=10 THEN S=S-7
440 R1=R2*16+S
450 NEXT I
460 ! EVALUATE RESULT
470 IF F$="C" THEN R=10000000*R2/R1
480 IF F$="F" THEN R=R1*16^6+R2
490 IF F$="G" THEN R=R2/R1
500 IF F$="I" THEN R=.0000001*R1/R2
510 IF F$="J" THEN R=.0000001*(R1*16^6+R2)
520 IF F$="K" THEN R=.0000001*R2/R1
530 IF M$="H" THEN R=R*60
540 IF M$="L" THEN R=R*256
550 IF M$="N" THEN R=R/10
560 IF M$="O" THEN R=R*10
570 IF M$="P" THEN R=R*1
580 DISP B$,R
590 NEXT K
600 LOCAL 710
610 END
Example of a result:
MEASURING TIME WILL BE
SELECTED BY HP85 (SINGLE)!
ANSWER Y WHEN READY TO START!
?
Y
MAKE 500 MEASUREMENTS
READY! ELAPSED TIME: 3.931 S
FIRST 5 RESULTS:
JP000000000031 .0000049
JP000000000030 .0000048
JP000000000031 .0000049
JP000000000031 .0000049
JP000000000031 .0000049
5053
Page: 32 GPIB-INTERFACE OPERATION
PM 6669 - OPERATORS MANUAL