HP 8924C - Page 41

41
S:\HP8924C\USRGUIDE\BOOK\chapters\getstart.fb
Chapter 1, Getting Started
HP-IB Command Guidelines
10 ! This program generates an FM carrier, measures and displays the
20 ! deviation, and draws the modulation waveform from the oscilloscope
30 ! to the CRT display. For demonstration purposes the
40 ! carrier is generated and analyzed through the uncalibrated input
50 ! path so that no external cables are required.
60 GCLEAR! Clear graphics display.
70 Bus=7! Interface select code of HP-IB interface
80 Dut=100*Bus+14! Default Test Set HP-IB address is 14
90 CLEAR Bus ! Good practice to clear the bus
100 CLEAR SCREEN ! Clear the CRT
110 OUTPUT Dut;”*RST” ! Preset the Test Set
120 OUTPUT Dut;”DISP DUPL” ! Display the DUPLEX TEST screen
130 OUTPUT Dut;”RFG:AMPL -14 DBM”! Set RF Gen Amplitude to -14 dBm
140 OUTPUT Dut;”AFAN:INP ’FM Demod’” ! Set AF Analyzer input to FM Demod
150 OUTPUT Dut;”AFAN:DET ’Pk+-Max’” ! Set AF Analyzer detector to Peak +/-Max
160 !
170 ! The following trigger guarantees that the instrument will auto-tune and
180 ! auto-range to the input signal before measuring.
190 !
200 OUTPUT Dut;”TRIG” ! Trigger all active measurements
210 OUTPUT Dut;”MEAS:AFR:FM?” ! Request an FM deviation measurement
220 ENTER Dut;Dev ! Read measured value into variable Dev
230 PRINT USING “K,D.DDD,K”;”Measured FM = “,Dev/1000,” kHz peak.”
240 DISP “’Continue’ when ready...” ! Set up user prompt
250 ON KEY 1 LABEL “Continue”,15 GOTO Proceed ! Set up interrupt on softkey 1
260 LOOP ! Loop until the key is pressed
270 END LOOP
280 Proceed: OFF KEY ! Turn off interrupt from softkey 1
290 DISP “” ! Clear the user prompt
300 !
310 ! Measure and plot an oscilloscope trace to see the waveform shape.
320 DIM Trace(0:416) ! Oscilloscope has 417 trace points
330 OUTPUT Dut;”DISP OSC” ! Display the OSCILLOSCOPE screen
340 OUTPUT Dut;”TRIG” ! Trigger all active measurements
350 OUTPUT Dut;”MEAS:OSC:TRAC?” ! Request the oscilloscope trace
360 ENTER Dut;Trace(*) ! Read the oscilloscope trace into array Trace(*)
370 !
380 ! CRT is (X,Y)=(0,0) in lower left corner to (399,179) upper right.
390 ! (Each pixel is about 0.02 mm wide by 0.03 mm tall, not square.)
400 ! Scale vertically for 0 kHz dev center-screen and +4 kHz dev top
410 ! of screen. Leave the next three lines for external control, or
420 ! comment them out for IBASIC (Test Set stand-alone) control.
430 !
440 PLOTTER IS CRT,”98627A” !Your display may have a different specifier.
450 GRAPHICS ON!Enable graphics to plot the waveform.
460 WINDOW 0,399,0,179
470 !
480 PEN 1 !Turn on drawing pen
490 MOVE 0,89.5+Trace(0)/4000*89.5
500 FOR I=1 TO 416
510 DRAW I/416*399,89.5+Trace(I)/4000*89.5
520 NEXT I
530 END