Keysight E4428C ESG RF User Manual

Keysight Signal Generators Programming Guide 89
Programming Examples
GPIB Programming Interface Examples
Queries Using HP Basic and GPIB
This example demonstrates signal generator query commands. The signal generator can be queried for
conditions and setup parameters. Query commands are identified by the question mark as in the
identify command *IDN? basicex3.txt performs the following functions:
• clears the signal generator
• queries the signal generator’s settings
The following program example is available on the signal generator Documentation CD- ROM as
basicex3.txt.
10 !********************************************************************************
20 !
30 ! PROGRAM NAME: basicex3.txt
40 !
50 ! PROGRAM DESCRIPTION: In this example, query commands are used with response
60 ! data formats.
70 !
80 ! CLEAR and RESET the controller and RUN the following program:
90 !
100 !********************************************************************************
110 !
120 DIM A$[10],C$[100],D$[10] ! Declares variables to hold string response data
130 INTEGER B ! Declares variable to hold integer response data
140 Sig_gen=719 ! Declares variable to hold signal generator address
150 LOCAL Sig_gen ! Puts signal generator in Local mode
160 CLEAR Sig_gen ! Resets parser and clears any pending output
170 CLEAR SCREEN ! Clears the controller’s display
180 OUTPUT Sig_gen;"*RST" ! Puts signal generator into a defined state
190 OUTPUT Sig_gen;"FREQ:CW?" ! Querys the signal generator CW frequency setting
200 ENTER Sig_gen;F ! Enter the CW frequency setting
210 ! Print frequency setting to the controller display
220 PRINT "Present source CW frequency is: ";F/1.E+6;"MHz"
230 PRINT
240 OUTPUT Sig_gen;"POW:AMPL?" ! Querys the signal generator power level
250 ENTER Sig_gen;W ! Enter the power level
260 ! Print power level to the controller display
270 PRINT "Current power setting is: ";W;"dBM"
280 PRINT
290 OUTPUT Sig_gen;"FREQ:MODE?" ! Querys the signal generator for frequency mode
300 ENTER Sig_gen;A$ ! Enter in the mode: CW, Fixed or List
310 ! Print frequency mode to the controller display
320 PRINT "Source's frequency mode is: ";A$
330 PRINT

Keysight E4428C ESG RF Specifications

General

Brand	Keysight
Model	E4428C ESG RF
Category	Portable Generator
Language	English