Siemens SINUMERIK 840D - Page 406

7 Configuring example 11.03
7.3 Safety Integrated with SPL
© Siemens AG 2003 All Rights Reserved
7-406 SINUMERIK 840D/SIMODRIVE 611 digital SINUMERIK Safety Integrated (FBSI) - Edition 11.03
FUNCTION FC 97: VOID
TITLE =Test stop
//Test stop activated after eight hours have elapsed and the protective door
has been opened
VERSION : 0.1
BEGIN
NETWORK
TITLE =Test stop step 1
//Forced checking procedure of the pulse cancellation
UN M 211.0; // Start monitoring time of 8 hours
L S5T#2H40M; // Load 2 hours and 40 minutes
SE T 30; // Start timer 30
//
U T 30; // After 2 hours and 40 minutes have elapsed
L S5T#2H40M; // Load 2 hours and 40 minutes
SE T 31; // Start timer 31
//
U T 31; // After 5 hours and 20 minutes have elapsed
L S5T#2H40M; // Load 2 hours and 40 minutes
SE T 32;
//
U T 32; // After 8 hours have elapsed and
UN E 76.1; // door not closed and interlocked
UN DB31.DBX 108.2; // Pulses not disabled (X)
UN DB32.DBX 108.2; // Pulses not cancelled (Z)
UN DB33.DBX 108.2; // Pulses not cancelled (C)
U DB31.DBX 110.5; // Axis X stopped
U DB32.DBX 110.5; // Axis Z stopped
U DB33.DBX 110.5; // Axis C stopped
S M 211.0; // Reset monitoring time of 8 hours
S M 211.1; // Start test stop 1
//
CALL FC 60 (// Test stop module
start := M 211.1,// Start test stop 1
reset := E 3.7,// Reset by RESET/MCP
num_axis := 2,// Number of drives
test_axis_1 := 1,// Drive number Axis X
test_axis_2 := 3,// Drive number spindle C
test_axis_3 := 0,
test_axis_4 := 0,
test_axis_5 := 0,
test_axis_6 := 0,
test_axis_7 := 0,
test_axis_8 := 0,
servo_test_out := A 49.0, // Test stop 1 NCK by A 49.0
aux_dword := MD 212, // Marker double word internal
ready := M 211.2, // Test stop 1 executed
error := M 211.7);// Error on test stop
//
U M 211.2; // Test stop 1 successfully executed
S M 211.3; // Start test stop 2
R M 211.2; // Test stop 1
//
CALL FC 60 (
start := M 211.3,// Start test stop 2
reset := E 3.7, // Reset by RESET/MCP
num_axis := 1, // 2 Number of drives
test_axis_1 := 2, // Drive number axis Z
test_axis_2 := 0,
test_axis_3 := 0,
test_axis_4 := 0,
test_axis_5 := 0,
test_axis_6 := 0,
test_axis_7 := 0,
test_axis_8 := 0,