Chapter 6 67
Reading Out Measured Result
Reading Out Measured Result
6. Reading out Measured
Result
Lines 390 to 410 Displays the measurement status, measured primary parameter result,
and measured secondary parameter result.
Line 430 If the Comp_flag value is 1 (the comparator function is ON), displays
the comparator sorting result.
Line 450 If the Comp_flag value is not 1 (the comparator function is OFF),
displays “Comparator : OFF.”
Example 6-3 Reading out the measured result in ASCII transfer format using the :FETC?
command (fetch_a.bas)
10 DIM Buff$[9]
20 REAL Pri_para,Sec_para
30 INTEGER Meas_stat,Comp
40 INTEGER Comp_flag
50 !
60 ASSIGN @Agt4288a TO 717
70 OUTPUT @Agt4288a;":FORM ASC"
80 !
90 OUTPUT @Agt4288a;":INIT:CONT ON"
100 OUTPUT @Agt4288a;":TRIG:SOUR EXT"
110 !
120 OUTPUT @Agt4288a;":CALC:COMP?"
130 ENTER @Agt4288a;Comp_flag
140 !
150 ! SRQ setting
160 !
170 OUTPUT @Agt4288a;":STAT:OPER:ENAB 16"
180 OUTPUT @Agt4288a;"*SRE 128"
190 OUTPUT @Agt4288a;"*CLS"
200 OUTPUT @Agt4288a;"*OPC?"
210 ENTER @Agt4288a;Buff$
220 !
230 ! Triggering and data read
240 !
250 ON INTR 7 GOTO Meas_end
260 ENABLE INTR 7;2
270 PRINT "Waiting for External Trigger!"
280 Meas_wait: GOTO Meas_wait
290 Meas_end: OFF INTR 7
300 OUTPUT @Agt4288a;":FETC?"
310 IF Comp_flag=1 THEN
320 ENTER @Agt4288a;Meas_stat,Pri_para,Sec_para,Comp
330 ELSE
340 ENTER @Agt4288a;Meas_stat,Pri_para,Sec_para
350 END IF
360 !
370 ! Display results
380 !
390 PRINT USING "15A,X,D";"Meas. status :",Meas_stat
400 PRINT USING "15A,X,SD.5DE";"Pri. parameter:",Pri_para
410 PRINT USING "15A,X,SD.5DE";"Sec. parameter:",Sec_para
420 IF Comp_flag=1 THEN
430 PRINT USING "15A,X,K";"Comparator :",Comp
440 ELSE
450 PRINT USING "19A";"Comparator : OFF"
460 END IF
470 END
To Next Page
Loading...
Need help?
General
