Agilent Technologies 4288A

Chapter 9 103
Measurement Applications (Sample Programs)
Basic Capacitor Measurement
9. Measurement Applications
(Sample Programs)
Lines 410 to 480 Displays the measured result.
Lines 500 to 510 Prompts the user to enter decision on whether to make the
measurement again. If the user presses the
[y] and [Enter] keys, returns
to the DUT connection stage and repeats the measurement.
Example 9-1 Capacitor measurement using test fixture (meas_fxt.bas)
10 DIM Pri$[9],Sec$[9],Inp_char$[9]
20 REAL Freq,Lvl,Pri_res,Sec_res
30 INTEGER Cbl,Result,Meas_stat
40 CLEAR SCREEN
50 !
60 ASSIGN @Agt4288a TO 717
70 !
80 Pri$="CP"
90 Sec$="Q"
100 Freq=1.E+6
110 Lvl=.5
120 Cbl=0
130 !
140 PRINT "Connect Test Fixture, then Push [Enter] key"
150 INPUT "",Inp_char$
160 !
170 OUTPUT @Agt4288a;":SYST:PRES"
180 !
190 OUTPUT @Agt4288a;":CALC1:FORM ";Pri$
200 OUTPUT @Agt4288a;":CALC2:FORM ";Sec$
210 OUTPUT @Agt4288a;":SOUR:FREQ ";Freq
220 OUTPUT @Agt4288a;":SOUR:VOLT ";Lvl
230 OUTPUT @Agt4288a;":CAL:CABL ";Cbl
240 !
250 Result=FNCompen(@Agt4288a,"Open",.00002)
260 IF Result<>0 THEN Prog_end
270 Result=FNCompen(@Agt4288a,"Short",20)
280 IF Result<>0 THEN Prog_end
290 !
300 OUTPUT @Agt4288a;":TRIG:SOUR BUS"
310 OUTPUT @Agt4288a;":INIT:CONT ON"
320 !
330 Meas_start: !
340 PRINT "Set DUT, then Push [Enter] key"
350 INPUT "",Inp_char$
360 OUTPUT @Agt4288a;"*TRG"
370 ENTER @Agt4288a;Meas_stat,Pri_res,Sec_res
380 !
390 ! Display results
400 !
410 PRINT "[MEASUREMENT RESULT]"
420 IF Meas_stat=1 THEN
430 PRINT USING "X,3A,6A";Pri$,": OVLD"
440 PRINT USING "X,3A,6A";Sec$,": OVLD"
450 ELSE
460 PRINT USING "X,3A,A,X,SD.5DE";Pri$,":",Pri_res
470 PRINT USING "X,3A,A,X,SD.5DE";Sec$,":",Sec_res
480 END IF
490 !
500 INPUT "Once more? [Y]es/[N]o",Inp_char$
510 IF UPC$(Inp_char$)="Y" OR UPC$(Inp_char$)="YES" THEN Meas_start
520 !
530 Prog_end: END
540 !=============================================
550 ! Compensation Data Measurement Function