44 Chapter 4
Preparation for Accurate Measurement (Executing Compensation)
Executing OPEN/SHORT/LOAD Compensation
Example 4-2 Recovering the compensation state (comp_dat.bas)
10 DIM File_name$[20],Load_para$[5],Img$[30]
20 REAL Freq(1:2),Open(1:2,1:2),Shor(1:2,1:2)
30 REAL Load(1:2,1:2),Load_ref(1:2,1:2)
40 INTEGER Cable,F_shift,Fr
50 CLEAR SCREEN
60 !
70 ASSIGN @Agt4288a TO 717
80 !
90 File_name$="Cmp_data"
100 !
110 PRINT "[Download Compensation data]"
120 ON ERROR GOTO File_error
130 ASSIGN @File TO File_name$;FORMAT OFF
140 ENTER @File;Cable,F_shift,Open(*),Shor(*),Load(*),Load_ref(*),Loa
d_para$
150 ASSIGN @File TO *
160 OFF ERROR
170 !
180 OUTPUT @Agt4288a;":CAL:CABL ";Cable
190 OUTPUT @Agt4288a;":SYST:FSH ";F_shift
200 OUTPUT @Agt4288a;":CORR:CKIT:STAN3:FORM "&Load_para$
210 PRINT "Cable :";Cable;"m"
220 PRINT "1MHz Shift:";F_shift;"%"
230 PRINT "Load para : ";Load_para$
240 !
250 Freq(1)=1.E+3
260 Freq(2)=1.E+6
270 FOR Fr=1 TO 2
280 OUTPUT @Agt4288a;":SOUR:FREQ ";Freq(Fr)
290 OUTPUT @Agt4288a;":CORR:DATA STAN1,";Open(Fr,1);",";Open(Fr,2)
300 OUTPUT @Agt4288a;":CORR:DATA STAN2,";Shor(Fr,1);",";Shor(Fr,2)
310 OUTPUT @Agt4288a;":CORR:DATA STAN3,";Load(Fr,1);",";Load(Fr,2)
320 OUTPUT @Agt4288a;":CORR:CKIT:STAN3";Load_ref(Fr,1);",";Load_ref
(Fr,2)
330 Img$="7A,MD.5DE,3X,MD.5DE"
340 PRINT "Frequency :";Freq(Fr);"Hz"
350 PRINT USING Img$;"Open : ",Open(Fr,1),Open(Fr,2)
360 PRINT USING Img$;"Short: ",Shor(Fr,1),Shor(Fr,2)
370 PRINT USING Img$;"Load : ",Load(Fr,1),Load(Fr,2)
380 PRINT USING Img$;" Ref : ",Load_ref(Fr,1),Load_ref(Fr,2)
390 NEXT Fr
400 !
410 OUTPUT @Agt4288a;":CORR:OPEN ON"
420 OUTPUT @Agt4288a;":CORR:SHOR ON"
430 OUTPUT @Agt4288a;":CORR:LOAD ON"
440 !
450 GOTO Prog_end
460 File_error: OFF ERROR
470 PRINT "################## ERROR ##################"
480 PRINT "The CAL_DATA (cal. coef. file) is NOT exist."
490 PRINT " or"
500 PRINT "The CAL_DATA's size is UNSUITABLE."
510 !
520 Prog_end: END
To Next Page
Loading...
Need help?
General
