Agilent Technologies 4288A

Chapter 6 63
Reading Out Measured Result
Reading Out Measured Result
6. Reading out Measured
Result
Example 6-1 Reading out the measured result in ASCII transfer format by using the *TRG
command (trg_a.bas)
10 DIM Buff$[9]
20 REAL Pri_para,Sec_para
30 INTEGER Meas_stat,Comp
40 INTEGER Comp_flag,Cond_reg
50 !
60 ASSIGN @Agt4288a TO 717
70 OUTPUT @Agt4288a;":FORM ASC"
80 !
90 OUTPUT @Agt4288a;":INIT:CONT ON"
100 OUTPUT @Agt4288a;":TRIG:SOUR BUS"
110 !
120 OUTPUT @Agt4288a;":CALC:COMP?"
130 ENTER @Agt4288a;Comp_flag
140 !
150 ! Triggering and data read
160 !
170 REPEAT
180 OUTPUT @Agt4288a;":STAT:OPER:COND?"
190 ENTER @Agt4288a;Cond_reg
200 UNTIL BIT(Cond_reg,5)
210 OUTPUT @Agt4288a;"*TRG"
220 IF Comp_flag=1 THEN
230 ENTER @Agt4288a;Meas_stat,Pri_para,Sec_para,Comp
240 ELSE
250 ENTER @Agt4288a;Meas_stat,Pri_para,Sec_para
260 END IF
270 !
280 ! Display results
290 !
300 PRINT USING "15A,X,D";"Meas. status :",Meas_stat
310 PRINT USING "15A,X,SD.5DE";"Pri. parameter:",Pri_para
320 PRINT USING "15A,X,SD.5DE";"Sec. parameter:",Sec_para
330 IF Comp_flag=1 THEN
340 PRINT USING "15A,X,K";"Comparator :",Comp
350 ELSE
360 PRINT USING "19A";"Comparator : OFF"
370 END IF
380 END